Mercurial > vim

view src/testdir/test_messages.vim @ 11629:1a6daa73590a v8.0.0697

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0697: recorded key sequences may become invalid commit https://github.com/vim/vim/commit/8858498516108432453526f07783f14c9196e112 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Jul 7 13:32:14 2017 +0200 patch 8.0.0697: recorded key sequences may become invalid Problem: Recorded key sequences may become invalid. Solution: Add back KE_SNIFF removed in 7.4.1433. Use fixed numbers for the key_extra enum.
author Christian Brabandt <cb@256bit.org>
date Fri, 07 Jul 2017 13:45:03 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction