Mercurial > vim

view src/testdir/test_messages.vim @ 12684:185f8dbdcf26 v8.0.1220

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1220: skipping empty statusline groups is not correct commit https://github.com/vim/vim/commit/235dddf1f4afe3a40047dbf2aca1bd177b7be18b Author: Bram Moolenaar <Bram@vim.org> Date: Thu Oct 26 18:21:24 2017 +0200 patch 8.0.1220: skipping empty statusline groups is not correct Problem: Skipping empty statusline groups is not correct. Solution: Also set group_end_userhl. (itchyny)
author Christian Brabandt <cb@256bit.org>
date Thu, 26 Oct 2017 18:30:05 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction