view runtime/ftplugin/modconf.vim @ 34108:14b69ff2c1ab v9.1.0018

patch 9.1.0018: use of #if instead of #ifdef Commit: https://github.com/vim/vim/commit/b52600d5613316e5b6e89514a02df1f97e27a5ff Author: Ken Takata <kentkt@csc.jp> Date: Fri Jan 12 17:31:07 2024 +0100 patch 9.1.0018: use of #if instead of #ifdef Problem: use of #if instead of #ifdef Solution: use correct form of #ifdef `#if FEAT_GUI_HAIKU` was used mistakenly. Use the correct form `#ifdef FEAT_GUI_HAIKU` instead. closes: #13843 Signed-off-by: Ken Takata <kentkt@csc.jp> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Fri, 12 Jan 2024 17:45:05 +0100
parents c252fbfde41d
children 89b487b08b2a
line wrap: on
line source

" Vim filetype plugin file
" Language:             modules.conf(5) configuration file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2023-10-07

if exists("b:did_ftplugin")
  finish
endif
let b:did_ftplugin = 1

let s:cpo_save = &cpo
set cpo&vim

let b:undo_ftplugin = "setl com< cms< inc< fo<"

setlocal comments=:# commentstring=#\ %s include=^\\s*include
setlocal formatoptions-=t formatoptions+=croql

if has('unix') && executable('less')
  if !has('gui_running')
    command -buffer -nargs=1 ModconfKeywordPrg
          \ silent exe '!' . 'LESS= MANPAGER="less --pattern=''^\s{,8}' . <q-args> . '\b'' --hilite-search" man ' . 'modprobe.d' |
          \ redraw!
  elseif has('terminal')
    command -buffer -nargs=1 ModconfKeywordPrg
          \ silent exe ':term ' . 'env LESS= MANPAGER="less --pattern=''' . escape('^\s{,8}' . <q-args> . '\b', '\') . ''' --hilite-search" man ' . 'modprobe.d'
  endif
  if exists(':ModconfKeywordPrg') == 2
    setlocal iskeyword+=-
    setlocal keywordprg=:ModconfKeywordPrg
    let b:undo_ftplugin .= '| setlocal keywordprg< iskeyword< | sil! delc -buffer ModconfKeywordPrg'
  endif
endif

let &cpo = s:cpo_save
unlet s:cpo_save