Mercurial > vim

view src/testdir/color_ramp.vim @ 25597:0fdacd8f0cf3 v8.2.3335

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.3335: Vim9: not enough tests run with Vim9 Commit: https://github.com/vim/vim/commit/ef98257593a0abf1300d0f70358dc45a70a62580 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Aug 12 19:27:57 2021 +0200 patch 8.2.3335: Vim9: not enough tests run with Vim9 Problem: Vim9: not enough tests run with Vim9. Solution: Run a few more tests in Vim9 script and :def function. Fix that items(), keys() and values9) return zero for a NULL dict. Make join() return an empty string for a NULL list. Make sort() return an empty list for a NULL list.
author Bram Moolenaar <Bram@vim.org>
date Thu, 12 Aug 2021 19:30:03 +0200
parents 89364104be93
children
line wrap: on
line source

" Script to generate a file that shows al 256 xterm colors

new
let lnum = 1

" | in original color pair to see white background.
let trail_bar = "\033[m|"

" ANSI colors
call setline(lnum, 'ANSI background')
let lnum += 1

let s = ''
for nr in range(0, 7)
  let s .= "\033[4" . nr . "m    "
endfor
for nr in range(8, 15)
  let s .= "\033[10" . (nr - 8) . "m    "
endfor
let s .= trail_bar

call setline(lnum, s)
let lnum += 1

" ANSI text colors
call setline(lnum, 'ANSI text')
let lnum += 1

let s = ''
for nr in range(0, 7)
  let s .= "\033[0;3" . nr . "mxxxx"
endfor
for nr in range(8, 15)
  let s .= "\033[0;9" . (nr - 8) . "mxxxx"
endfor
let s .= trail_bar

call setline(lnum, s)
let lnum += 1

" ANSI with bold text
call setline(lnum, 'ANSI bold text')
let lnum += 1

let s = ''
for nr in range(0, 7)
  let s .= "\033[1;3" . nr . "mxxxx"
endfor
for nr in range(8, 15)
  let s .= "\033[1;9" . (nr - 8) . "mxxxx"
endfor
let s .= trail_bar

call setline(lnum, s)
let lnum += 1

" 6 x 6 x 6 color cube
call setline(lnum, 'color cube')
let lnum += 1

for high in range(0, 5)
  let s = ''
  for low in range(0, 35)
    let nr = low + high * 36
    let s .= "\033[48;5;" . (nr + 16) . "m  "
  endfor
  let s .= trail_bar
  call setline(lnum + high, s)
endfor
let lnum += 6

" 24 shades of grey
call setline(lnum, 'grey ramp')
let lnum += 1

let s = ''
for nr in range(0, 23)
    let s .= "\033[48;5;" . (nr + 232) . "m   "
endfor
let s .= trail_bar
call setline(lnum, s)

set binary
write! <sfile>:h/color_ramp.txt
quit