Mercurial > vim

view src/testdir/test_tabline.vim @ 13180:0dfd846f9190 v8.0.1464

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1464: completing directory after :find does not add slash commit https://github.com/vim/vim/commit/8a37b032895b40dd6953280c33585bcba0c7ef8b Author: Bram Moolenaar <Bram@vim.org> Date: Sat Feb 3 20:43:08 2018 +0100 patch 8.0.1464: completing directory after :find does not add slash Problem: Completing directory after :find does not add slash. Solution: Adjust the flags for globpath(). (Genki Sky)
author Christian Brabandt <cb@256bit.org>
date Sat, 03 Feb 2018 20:45:06 +0100
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction