Mercurial > vim

view src/testdir/test_messages.vim @ 13322:0dc2e4998a15 v8.0.1535

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1535: C syntax test still fails when using gvim commit https://github.com/vim/vim/commit/6acadda8d60892ddf06449f1cc4286912b0c0c2b Author: Bram Moolenaar <Bram@vim.org> Date: Sat Feb 24 16:51:32 2018 +0100 patch 8.0.1535: C syntax test still fails when using gvim Problem: C syntax test still fails when using gvim. Solution: Clear Normal cterm highlighting instead of setting it.
author Christian Brabandt <cb@256bit.org>
date Sat, 24 Feb 2018 17:00:07 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction