Mercurial > vim

view src/testdir/test_messages.vim @ 10855:0beffabed338 v8.0.0317

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0317: no test for setting 'guifont' commit https://github.com/vim/vim/commit/43dded8c59c0647a70dd52c3125783945d90ae5a Author: Bram Moolenaar <Bram@vim.org> Date: Thu Feb 9 16:06:17 2017 +0100 patch 8.0.0317: no test for setting 'guifont' Problem: No test for setting 'guifont'. Solution: Add a test for X11 GUIs. (Kazunobu Kuriyama)
author Christian Brabandt <cb@256bit.org>
date Thu, 09 Feb 2017 16:15:05 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction