Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 24172:09598e5ced97 v8.2.2627

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.2627: no need to check for BSD after checking for not root Commit: https://github.com/vim/vim/commit/4355894869355c185e7810e67d52802453576e81 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Mar 20 12:49:15 2021 +0100 patch 8.2.2627: no need to check for BSD after checking for not root Problem: No need to check for BSD after checking for not root. Solution: Remove CheckNotBSD. (Ozaki Kiichi, closes https://github.com/vim/vim/issues/7989)
author Bram Moolenaar <Bram@vim.org>
date Sat, 20 Mar 2021 13:00:03 +0100
parents 08940efa6b4e
children dbec60b8c253
line wrap: on
line source

" Test for expanding dllpath options

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')

" vim: shiftwidth=2 sts=2 expandtab