Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 17223:07bbe73b8e74 v8.1.1611

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1611: bufadd() reuses existing buffer without a name commit https://github.com/vim/vim/commit/892ae723ab95e429222e930cf41b32809567e58e Author: Bram Moolenaar <Bram@vim.org> Date: Sun Jun 30 20:33:01 2019 +0200 patch 8.1.1611: bufadd() reuses existing buffer without a name Problem: Bufadd() reuses existing buffer without a name. Solution: When the name is empty always create a new buffer.
author Bram Moolenaar <Bram@vim.org>
date Sun, 30 Jun 2019 20:45:05 +0200
parents 18cda18a38e2
children 08940efa6b4e
line wrap: on
line source

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')