Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 22614:048a3033d19c v8.2.1855

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.1855: Vim9: get error message when nothing is wrong Commit: https://github.com/vim/vim/commit/e13bdec6b90b3a0fce4f021e3ee986e731cea3b5 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Oct 16 23:16:47 2020 +0200 patch 8.2.1855: Vim9: get error message when nothing is wrong Problem: Vim9: get error message when nothing is wrong. Solution: Check called_emsg instead of did_emsg. (closes https://github.com/vim/vim/issues/7143)
author Bram Moolenaar <Bram@vim.org>
date Fri, 16 Oct 2020 23:30:03 +0200
parents 08940efa6b4e
children dbec60b8c253
line wrap: on
line source

" Test for expanding dllpath options

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')

" vim: shiftwidth=2 sts=2 expandtab