changeset 14595:2b9c586918f8 v8.1.0311

patch 8.1.0311: filtering entries in a quickfix list is not easy commit https://github.com/vim/vim/commit/8c5e0093c9badced73e382915fb024a5c3ea463b Author: Bram Moolenaar <Bram@vim.org> Date: Tue Aug 21 19:22:23 2018 +0200 patch 8.1.0311: filtering entries in a quickfix list is not easy Problem: Filtering entries in a quickfix list is not easy. Solution: Add the cfilter plugin. (Yegappan Lakshmanan)
author Christian Brabandt <cb@256bit.org>
date Tue, 21 Aug 2018 19:30:06 +0200
parents a1480053df74
children aca7414636ed
files runtime/doc/quickfix.txt runtime/pack/dist/opt/cfilter/plugin/cfilter.vim src/version.c
diffstat 3 files changed, 61 insertions(+), 0 deletions(-) [+]
line wrap: on
line diff
--- a/runtime/doc/quickfix.txt
+++ b/runtime/doc/quickfix.txt
@@ -1551,6 +1551,22 @@ The backslashes before the pipe characte
 recognized as a command separator.  The backslash before each space is
 required for the set command.
 
+						*cfilter-plugin*
+If you have too many matching messages, you can use the cfilter plugin to
+reduce the number of entries.  Load the plugin with: >
+   packadd cfilter
+
+Then you can use these command: >
+   :Cfilter[!] {pat}
+   :Lfilter[!] {pat}
+
+:Cfilter creates a new quickfix list from entries matching {pat} in the
+current quickfix list. Both the file name and the text of the entries are
+matched against {pat}. If ! is supplied, then entries not matching {pat} are
+used.
+
+:Lfilter does the same as :Cfilter but operates on the current location list.
+
 =============================================================================
 8. The directory stack				*quickfix-directory-stack*
 
new file mode 100644
--- /dev/null
+++ b/runtime/pack/dist/opt/cfilter/plugin/cfilter.vim
@@ -0,0 +1,43 @@
+" cfilter.vim: Plugin to filter entries from a quickfix/location list
+" Last Change: 	May 12, 2018
+" Maintainer: 	Yegappan Lakshmanan (yegappan AT yahoo DOT com)
+" Version:	1.0
+"
+" Commands to filter the quickfix list:
+"   :Cfilter[!] {pat}
+"       Create a new quickfix list from entries matching {pat} in the current
+"       quickfix list. Both the file name and the text of the entries are
+"       matched against {pat}. If ! is supplied, then entries not matching
+"       {pat} are used.
+"   :Lfilter[!] {pat}
+"       Same as :Cfilter but operates on the current location list.
+"
+if exists("loaded_cfilter")
+    finish
+endif
+let loaded_cfilter = 1
+
+func s:Qf_filter(qf, pat, bang)
+    if a:qf
+	let Xgetlist = function('getqflist')
+	let Xsetlist = function('setqflist')
+	let cmd = ':Cfilter' . a:bang
+    else
+	let Xgetlist = function('getloclist', [0])
+	let Xsetlist = function('setloclist', [0])
+	let cmd = ':Lfilter' . a:bang
+    endif
+
+    if a:bang == '!'
+	let cond = 'v:val.text !~# a:pat && bufname(v:val.bufnr) !~# a:pat'
+    else
+	let cond = 'v:val.text =~# a:pat || bufname(v:val.bufnr) =~# a:pat'
+    endif
+
+    let items = filter(Xgetlist(), cond)
+    let title = cmd . ' ' . a:pat
+    call Xsetlist([], ' ', {'title' : title, 'items' : items})
+endfunc
+
+com! -nargs=+ -bang Cfilter call s:Qf_filter(1, <q-args>, <q-bang>)
+com! -nargs=+ -bang Lfilter call s:Qf_filter(0, <q-args>, <q-bang>)
--- a/src/version.c
+++ b/src/version.c
@@ -795,6 +795,8 @@ static char *(features[]) =
 static int included_patches[] =
 {   /* Add new patch number below this line */
 /**/
+    311,
+/**/
     310,
 /**/
     309,