Mercurial > vim

view runtime/autoload/freebasic.vim @ 29653:aa83cf7bef1c v9.0.0167

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.0167: checking for text properties could be a bit more efficient Commit: https://github.com/vim/vim/commit/38ea2733b4dd8e9bfc4a5bb5c11cb661bf000c4e Author: Bram Moolenaar <Bram@vim.org> Date: Sun Aug 7 22:04:56 2022 +0100 patch 9.0.0167: checking for text properties could be a bit more efficient Problem: Checking for text properties could be a bit more efficient. Solution: Return early when there are no text properties. Update TODO items.
author Bram Moolenaar <Bram@vim.org>
date Sun, 07 Aug 2022 23:15:03 +0200
parents 912224cab37f
children
line wrap: on
line source

" Vim filetype plugin file
" Language:	FreeBASIC
" Maintainer:	Doug Kearns <dougkearns@gmail.com>
" Last Change:	2022 June 24

" Dialects can be one of fb, qb, fblite, or deprecated
" Precedence is forcelang > #lang > lang
function! freebasic#GetDialect() abort
  if exists("g:freebasic_forcelang")
    return g:freebasic_forcelang
  endif

  if exists("g:freebasic_lang")
    let dialect = g:freebasic_lang
  else
    let dialect = "fb"
  endif

  " override with #lang directive or metacommand

  let pat = '\c^\s*\%(#\s*lang\s\+\|''\s*$lang\s*:\s*\)"\([^"]*\)"'

  let save_cursor = getcurpos()
  call cursor(1, 1)
  let lnum = search(pat, 'cn')
  call setpos('.', save_cursor)

  if lnum
    let word = matchlist(getline(lnum), pat)[1]
    if word =~? '\<\%(fb\|deprecated\|fblite\|qb\)\>'
      let dialect = word
    else
      echomsg "freebasic#GetDialect: Invalid lang, found '" .. word .. "' at line " .. lnum .. " " .. getline(lnum)
    endif
  endif

  return dialect
endfunction

" vim: nowrap sw=2 sts=2 ts=8 noet fdm=marker: