view runtime/ftplugin.vim @ 28297:4190b932e6ca v8.2.4674

patch 8.2.4674: cannot force getting MouseMove events Commit: https://github.com/vim/vim/commit/c4cb544cd5beaa864b3893e4b8d0085393c7dbce Author: Ernie Rael <errael@raelity.com> Date: Sun Apr 3 15:47:28 2022 +0100 patch 8.2.4674: cannot force getting MouseMove events Problem: Cannot force getting MouseMove events. Solution: Add the 'mousemoveevent' option with implementaiton for the GUI. (Ernie Rael, closes #10044)
author Bram Moolenaar <Bram@vim.org>
date Sun, 03 Apr 2022 17:00:04 +0200
parents 9fe2fed9bb4b
children 4027cefc2aab
line wrap: on
line source

vim9script noclear

# Vim support file to switch on loading plugins for file types
#
# Maintainer:	Bram Moolenaar <Bram@vim.org>
# Last change:	2022 Feb 11

if exists("g:did_load_ftplugin")
  finish
endif
g:did_load_ftplugin = 1

augroup filetypeplugin
  au FileType * call LoadFTPlugin()
augroup END

if exists('*LoadFTPlugin')
  # No need to define the function again.
  finish
endif

def LoadFTPlugin()
  if exists("b:undo_ftplugin")
    # We assume b:undo_ftplugin is using legacy script syntax
    legacy exe b:undo_ftplugin
    unlet! b:undo_ftplugin b:did_ftplugin
  endif

  var s = expand("<amatch>")
  if s != ""
    if &cpo =~# "S" && exists("b:did_ftplugin")
      # In compatible mode options are reset to the global values, need to
      # set the local values also when a plugin was already used.
      unlet b:did_ftplugin
    endif

    # When there is a dot it is used to separate filetype names.  Thus for
    # "aaa.bbb" load "aaa" and then "bbb".
    for name in split(s, '\.')
      exe 'runtime! ftplugin/' .. name .. '.vim ftplugin/' .. name .. '_*.vim ftplugin/' .. name .. '/*.vim'
    endfor
  endif
enddef