Mercurial > vim

view runtime/syntax/services.vim @ 24721:8a3659f78064 v8.2.2899

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.2899: Appveyor script does not detect nmake failure Commit: https://github.com/vim/vim/commit/f89be8de14cc9055d12f7b0f2c270a5bc09fc86c Author: K.Takata <kentkt@csc.jp> Date: Sat May 29 12:42:47 2021 +0200 patch 8.2.2899: Appveyor script does not detect nmake failure Problem: Appveyor script does not detect nmake failure. Solution: Explicitly check for executable. (Ken Takata, closes https://github.com/vim/vim/issues/8281)
author Bram Moolenaar <Bram@vim.org>
date Sat, 29 May 2021 12:45:02 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             services(5) - Internet network services list
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   servicesBegin     display '^'
                              \ nextgroup=servicesName,servicesComment

syn match   servicesName      contained display '[[:graph:]]\+'
                              \ nextgroup=servicesPort skipwhite

syn match   servicesPort      contained display '\d\+'
                              \ nextgroup=servicesPPDiv,servicesPPDivDepr
                              \ skipwhite

syn match   servicesPPDiv     contained display '/'
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesPPDivDepr contained display ','
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesProtocol  contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn match   servicesAliases   contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn keyword servicesTodo      contained TODO FIXME XXX NOTE

syn region  servicesComment   display oneline start='#' end='$'
                              \ contains=servicesTodo,@Spell

hi def link servicesTodo      Todo
hi def link servicesComment   Comment
hi def link servicesName      Identifier
hi def link servicesPort      Number
hi def link servicesPPDiv     Delimiter
hi def link servicesPPDivDepr Error
hi def link servicesProtocol  Type
hi def link servicesAliases   Macro

let b:current_syntax = "services"

let &cpo = s:cpo_save
unlet s:cpo_save