Mercurial > vim

view src/testdir/test_changelist.vim @ 24570:27033b8bba0e v8.2.2824

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.2824: MS-Windows: build failure with MSVC Commit: https://github.com/vim/vim/commit/1bb0da25a6581cd09d6df91f11ce866dc775597b Author: Bram Moolenaar <Bram@vim.org> Date: Sun May 2 19:15:05 2021 +0200 patch 8.2.2824: MS-Windows: build failure with MSVC Problem: MS-Windows: build failure with MSVC. Solution: Adjust the list of distributed files. Add hint about python. Adjust path for reading runtime files.
author Bram Moolenaar <Bram@vim.org>
date Sun, 02 May 2021 19:30:04 +0200
parents 08940efa6b4e
children 255bc9a08e58
line wrap: on
line source

" Tests for the changelist functionality

source check.vim

" Tests for the getchangelist() function
func Test_getchangelist()
  CheckFeature jumplist

  bwipe!
  enew
  call assert_equal([], 10->getchangelist())
  call assert_equal([[], 0], getchangelist())

  call writefile(['line1', 'line2', 'line3'], 'Xfile1.txt')
  call writefile(['line1', 'line2', 'line3'], 'Xfile2.txt')

  edit Xfile1.txt
  exe "normal 1Goline\<C-G>u1.1"
  exe "normal 3Goline\<C-G>u2.1"
  exe "normal 5Goline\<C-G>u3.1"
  normal g;
  call assert_equal([[
	      \ {'lnum' : 2, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 4, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 6, 'col' : 4, 'coladd' : 0}], 2],
	      \ getchangelist('%'))

  hide edit Xfile2.txt
  exe "normal 1GOline\<C-G>u1.0"
  exe "normal 2Goline\<C-G>u2.0"
  call assert_equal([[
	      \ {'lnum' : 1, 'col' : 6, 'coladd' : 0},
	      \ {'lnum' : 3, 'col' : 6, 'coladd' : 0}], 2],
	      \ getchangelist('%'))
  hide enew

  call assert_equal([[
	      \ {'lnum' : 2, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 4, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 6, 'col' : 4, 'coladd' : 0}], 3], getchangelist(2))
  call assert_equal([[
	      \ {'lnum' : 1, 'col' : 6, 'coladd' : 0},
	      \ {'lnum' : 3, 'col' : 6, 'coladd' : 0}], 2], getchangelist(3))

  bwipe!
  call delete('Xfile1.txt')
  call delete('Xfile2.txt')
endfunc

" vim: shiftwidth=2 sts=2 expandtab