Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 22172:1b23391fac7e v8.2.1635

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.1635: no digraph for 0x2022 BULLET Commit: https://github.com/vim/vim/commit/57ad94c5a9ee6f3626e1ec728519a8558a4346c8 Author: Bram Moolenaar <Bram@vim.org> Date: Tue Sep 8 19:06:30 2020 +0200 patch 8.2.1635: no digraph for 0x2022 BULLET Problem: No digraph for 0x2022 BULLET. Solution: Use "oo". (Hans Ginzel, closes https://github.com/vim/vim/issues/6904)
author Bram Moolenaar <Bram@vim.org>
date Tue, 08 Sep 2020 19:15:05 +0200
parents 08940efa6b4e
children dbec60b8c253
line wrap: on
line source

" Test for expanding dllpath options

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')

" vim: shiftwidth=2 sts=2 expandtab