Mercurial > vim

view runtime/indent/rnoweb.vim @ 20994:15ef156a6e75 v8.2.1048

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.1048: build failure without the eval feature Commit: https://github.com/vim/vim/commit/9d40c63c7dc8c3eb3886c58dcd334bc7f37eceba Author: Bram Moolenaar <Bram@vim.org> Date: Wed Jun 24 19:05:29 2020 +0200 patch 8.2.1048: build failure without the eval feature Problem: Build failure without the eval feature. Solution: Add dummy typedef.
author Bram Moolenaar <Bram@vim.org>
date Wed, 24 Jun 2020 19:15:04 +0200
parents 0ecb909e3249
children b2412874362f
line wrap: on
line source

" Vim indent file
" Language:	Rnoweb
" Author:	Jakson Alves de Aquino <jalvesaq@gmail.com>
" Homepage:     https://github.com/jalvesaq/R-Vim-runtime
" Last Change:	Fri Apr 15, 2016  10:58PM


" Only load this indent file when no other was loaded.
if exists("b:did_indent")
  finish
endif
runtime indent/tex.vim

function! s:NoTeXIndent()
  return indent(line("."))
endfunction

if &indentexpr == "" || &indentexpr == "GetRnowebIndent()"
  let s:TeXIndent = function("s:NoTeXIndent")
else
  let s:TeXIndent = function(substitute(&indentexpr, "()", "", ""))
endif

unlet! b:did_indent
runtime indent/r.vim
let s:RIndent = function(substitute(&indentexpr, "()", "", ""))
let b:did_indent = 1

setlocal indentkeys=0{,0},!^F,o,O,e,},=\bibitem,=\item
setlocal indentexpr=GetRnowebIndent()

if exists("*GetRnowebIndent")
  finish
endif

function GetRnowebIndent()
  let curline = getline(".")
  if curline =~ '^<<.*>>=$' || curline =~ '^\s*@$'
    return 0
  endif
  if search("^<<", "bncW") > search("^@", "bncW")
    return s:RIndent()
  endif
  return s:TeXIndent()
endfunction

" vim: sw=2