Mercurial > vim

view src/testdir/color_ramp.vim @ 19868:a2fa2fc0f403 v8.2.0490

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0490: Win32: VTP doesn't respect 'restorescreen' Commit: https://github.com/vim/vim/commit/0afdcf8601792ee751984265b49fc2ca6f8ea858 Author: Bram Moolenaar <Bram@vim.org> Date: Wed Apr 1 18:29:10 2020 +0200 patch 8.2.0490: Win32: VTP doesn't respect 'restorescreen' Problem: Win32: VTP doesn't respect 'restorescreen'. Solution: Use escape codes to switch to alternate screen. (Nobuhiro Takasaki, closes #5872)
author Bram Moolenaar <Bram@vim.org>
date Wed, 01 Apr 2020 18:30:03 +0200
parents 2d54f1e7ba0f
children 89364104be93
line wrap: on
line source

" Script to generate a file that shows al 256 xterm colors

new
call setline(1, 'ANSI')

" ANSI colors
let s = ''
for nr in range(0, 7)
  let s .= "\033[4" . nr . "m    "
endfor
for nr in range(8, 15)
  let s .= "\033[10" . (nr - 8) . "m    "
endfor
" Add | in original color pair to see white background.
let s .= "\033[m|"
call setline(2, s)

" 6 x 6 x 6 color cube
call setline(3, 'color cube')
for high in range(0, 5)
  let s = ''
  for low in range(0, 35)
    let nr = low + high * 36
    let s .= "\033[48;5;" . (nr + 16) . "m  "
  endfor
  let s .= "\033[m|"
  call setline(high + 4, s)
endfor

" 24 shades of grey
call setline(10, 'grey ramp')
let s = ''
for nr in range(0, 23)
    let s .= "\033[48;5;" . (nr + 232) . "m   "
endfor
let s .= "\033[m|"
call setline(11, s)

set binary
write! <sfile>:h/color_ramp.txt
quit