Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 19854:eddc81783052 v8.2.0483

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0483: Vim9: "let x = x + 1" does not give an error Commit: https://github.com/vim/vim/commit/d25ec2cfa0c25c3b00b7f8963b8aea799df1f20a Author: Bram Moolenaar <Bram@vim.org> Date: Mon Mar 30 21:05:45 2020 +0200 patch 8.2.0483: Vim9: "let x = x + 1" does not give an error Problem: Vim9: "let x = x + 1" does not give an error. Solution: Hide the variable when compiling the expression.
author Bram Moolenaar <Bram@vim.org>
date Mon, 30 Mar 2020 21:15:03 +0200
parents 18cda18a38e2
children 08940efa6b4e
line wrap: on
line source

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')