Mercurial > vim

view runtime/syntax/services.vim @ 18275:5218e26c658f v8.1.2132

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.2132: MS-Windows: screen mess when not recognizing insider build Commit: https://github.com/vim/vim/commit/a129974bc71fcb86e05a29387bcaba9aae2f296a Author: Bram Moolenaar <Bram@vim.org> Date: Thu Oct 10 16:36:00 2019 +0200 patch 8.1.2132: MS-Windows: screen mess when not recognizing insider build Problem: MS-Windows: screen mess when not recognizing insider build. Solution: Always move the cursor to the first column first. (Nobuhiro Takasaki, closes #5036)
author Bram Moolenaar <Bram@vim.org>
date Thu, 10 Oct 2019 16:45:03 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             services(5) - Internet network services list
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   servicesBegin     display '^'
                              \ nextgroup=servicesName,servicesComment

syn match   servicesName      contained display '[[:graph:]]\+'
                              \ nextgroup=servicesPort skipwhite

syn match   servicesPort      contained display '\d\+'
                              \ nextgroup=servicesPPDiv,servicesPPDivDepr
                              \ skipwhite

syn match   servicesPPDiv     contained display '/'
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesPPDivDepr contained display ','
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesProtocol  contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn match   servicesAliases   contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn keyword servicesTodo      contained TODO FIXME XXX NOTE

syn region  servicesComment   display oneline start='#' end='$'
                              \ contains=servicesTodo,@Spell

hi def link servicesTodo      Todo
hi def link servicesComment   Comment
hi def link servicesName      Identifier
hi def link servicesPort      Number
hi def link servicesPPDiv     Delimiter
hi def link servicesPPDivDepr Error
hi def link servicesProtocol  Type
hi def link servicesAliases   Macro

let b:current_syntax = "services"

let &cpo = s:cpo_save
unlet s:cpo_save