view runtime/indent/rrst.vim @ 17752:6e11a5cb1533 v8.1.1873

patch 8.1.1873: cannot build tiny version commit https://github.com/vim/vim/commit/df707755554ecc102a908e8d5b64f2903f4f3686 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Aug 17 17:50:07 2019 +0200 patch 8.1.1873: cannot build tiny version Problem: Cannot build tiny version. Solution: Remove #ifdef for is_autocmd_blocked().
author Bram Moolenaar <Bram@vim.org>
date Sat, 17 Aug 2019 18:00:03 +0200
parents da01d5da2cfa
children b2412874362f
line wrap: on
line source

" Vim indent file
" Language:	Rrst
" Author:	Jakson Alves de Aquino <jalvesaq@gmail.com>
" Homepage:     https://github.com/jalvesaq/R-Vim-runtime
" Last Change:	Tue Apr 07, 2015  04:38PM


" Only load this indent file when no other was loaded.
if exists("b:did_indent")
  finish
endif
runtime indent/r.vim
let s:RIndent = function(substitute(&indentexpr, "()", "", ""))
let b:did_indent = 1

setlocal indentkeys=0{,0},:,!^F,o,O,e
setlocal indentexpr=GetRrstIndent()

if exists("*GetRrstIndent")
  finish
endif

function GetRstIndent()
  let pline = getline(v:lnum - 1)
  let cline = getline(v:lnum)
  if prevnonblank(v:lnum - 1) < v:lnum - 1 || cline =~ '^\s*[-\+\*]\s' || cline =~ '^\s*\d\+\.\s\+'
    return indent(v:lnum)
  elseif pline =~ '^\s*[-\+\*]\s'
    return indent(v:lnum - 1) + 2
  elseif pline =~ '^\s*\d\+\.\s\+'
    return indent(v:lnum - 1) + 3
  endif
  return indent(prevnonblank(v:lnum - 1))
endfunction

function GetRrstIndent()
  if getline(".") =~ '^\.\. {r .*}$' || getline(".") =~ '^\.\. \.\.$'
    return 0
  endif
  if search('^\.\. {r', "bncW") > search('^\.\. \.\.$', "bncW")
    return s:RIndent()
  else
    return GetRstIndent()
  endif
endfunction

" vim: sw=2