Mercurial > vim

view runtime/indent/rnoweb.vim @ 17425:6580e2dfcaeb v8.1.1711

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1711: listener callback called at the wrong moment commit https://github.com/vim/vim/commit/acf7544cf62227972eeb063d6d9ecddaa5682a73 Author: Bram Moolenaar <Bram@vim.org> Date: Wed Jul 17 22:55:35 2019 +0200 patch 8.1.1711: listener callback called at the wrong moment Problem: Listener callback called at the wrong moment Solution: Invoke listeners before calling ml_delete_int(). (closes https://github.com/vim/vim/issues/4657)
author Bram Moolenaar <Bram@vim.org>
date Wed, 17 Jul 2019 23:00:06 +0200
parents 0ecb909e3249
children b2412874362f
line wrap: on
line source

" Vim indent file
" Language:	Rnoweb
" Author:	Jakson Alves de Aquino <jalvesaq@gmail.com>
" Homepage:     https://github.com/jalvesaq/R-Vim-runtime
" Last Change:	Fri Apr 15, 2016  10:58PM


" Only load this indent file when no other was loaded.
if exists("b:did_indent")
  finish
endif
runtime indent/tex.vim

function! s:NoTeXIndent()
  return indent(line("."))
endfunction

if &indentexpr == "" || &indentexpr == "GetRnowebIndent()"
  let s:TeXIndent = function("s:NoTeXIndent")
else
  let s:TeXIndent = function(substitute(&indentexpr, "()", "", ""))
endif

unlet! b:did_indent
runtime indent/r.vim
let s:RIndent = function(substitute(&indentexpr, "()", "", ""))
let b:did_indent = 1

setlocal indentkeys=0{,0},!^F,o,O,e,},=\bibitem,=\item
setlocal indentexpr=GetRnowebIndent()

if exists("*GetRnowebIndent")
  finish
endif

function GetRnowebIndent()
  let curline = getline(".")
  if curline =~ '^<<.*>>=$' || curline =~ '^\s*@$'
    return 0
  endif
  if search("^<<", "bncW") > search("^@", "bncW")
    return s:RIndent()
  endif
  return s:TeXIndent()
endfunction

" vim: sw=2