Mercurial > vim

view runtime/indent.vim @ 16638:4790302965fc v8.1.1321

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1321: no docs or tests for listener functions commit https://github.com/vim/vim/commit/a334772967de25764ed7b11d768e8b977818d0c6 Author: Bram Moolenaar <Bram@vim.org> Date: Sat May 11 21:14:24 2019 +0200 patch 8.1.1321: no docs or tests for listener functions Problem: No docs or tests for listener functions. Solution: Add help and tests for listener_add() and listener_remove(). Invoke the callbacks before redrawing.
author Bram Moolenaar <Bram@vim.org>
date Sat, 11 May 2019 21:15:06 +0200
parents 19ef2bbf569c
children f37561549ec2
line wrap: on
line source

" Vim support file to switch on loading indent files for file types
"
" Maintainer:	Bram Moolenaar <Bram@vim.org>
" Last Change:	2008 Feb 22

if exists("did_indent_on")
  finish
endif
let did_indent_on = 1

augroup filetypeindent
  au FileType * call s:LoadIndent()
  func! s:LoadIndent()
    if exists("b:undo_indent")
      exe b:undo_indent
      unlet! b:undo_indent b:did_indent
    endif
    let s = expand("<amatch>")
    if s != ""
      if exists("b:did_indent")
	unlet b:did_indent
      endif

      " When there is a dot it is used to separate filetype names.  Thus for
      " "aaa.bbb" load "indent/aaa.vim" and then "indent/bbb.vim".
      for name in split(s, '\.')
	exe 'runtime! indent/' . name . '.vim'
      endfor
    endif
  endfunc
augroup END