Mercurial > vim

view src/testdir/test_tabline.vim @ 15168:1cc5524d1081 v8.1.0594

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.0594: libvterm tests fail to run on Mac commit https://github.com/vim/vim/commit/8b321d6a521e76c5cbe640272574e4fbd42cba9b Author: Bram Moolenaar <Bram@vim.org> Date: Sat Dec 15 15:39:28 2018 +0100 patch 8.1.0594: libvterm tests fail to run on Mac Problem: Libvterm tests fail to run on Mac. Solution: Only run libvterm tests on Linux.
author Bram Moolenaar <Bram@vim.org>
date Sat, 15 Dec 2018 15:45:05 +0100
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction