Mercurial > vim

view runtime/autoload/paste.vim @ 15140:fd2286799026 v8.1.0580

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.0580: invalid memory access when using text properties commit https://github.com/vim/vim/commit/2fa7fad831a860b627b5d6980aae0eeebfda0b3b Author: Bram Moolenaar <Bram@vim.org> Date: Thu Dec 13 23:05:56 2018 +0100 patch 8.1.0580: invalid memory access when using text properties Problem: Invalid memory access when using text properties. Solution: Disable text properties for now.
author Bram Moolenaar <Bram@vim.org>
date Thu, 13 Dec 2018 23:15:05 +0100
parents d91cf2e26ef0
children fe57e4f0eac1
line wrap: on
line source

" Vim support file to help with paste mappings and menus
" Maintainer:	Bram Moolenaar <Bram@vim.org>
" Last Change:	2017 Aug 30

" Define the string to use for items that are present both in Edit, Popup and
" Toolbar menu.  Also used in mswin.vim and macmap.vim.

" Pasting blockwise and linewise selections is not possible in Insert and
" Visual mode without the +virtualedit feature.  They are pasted as if they
" were characterwise instead.  Add to that some tricks to leave the cursor in
" the right position, also for "gi".
if has("virtualedit")
  let paste#paste_cmd = {'n': ":call paste#Paste()<CR>"}
  let paste#paste_cmd['v'] = '"-c<Esc>' . paste#paste_cmd['n']
  let paste#paste_cmd['i'] = "\<c-\>\<c-o>\"+gP"

  func! paste#Paste()
    let ove = &ve
    set ve=all
    normal! `^
    if @+ != ''
      normal! "+gP
    endif
    let c = col(".")
    normal! i
    if col(".") < c	" compensate for i<ESC> moving the cursor left
      normal! l
    endif
    let &ve = ove
  endfunc
else
  let paste#paste_cmd = {'n': "\"=@+.'xy'<CR>gPFx\"_2x"}
  let paste#paste_cmd['v'] = '"-c<Esc>gix<Esc>' . paste#paste_cmd['n'] . '"_x'
  let paste#paste_cmd['i'] = 'x<Esc>' . paste#paste_cmd['n'] . '"_s'
endif