view runtime/indent.vim @ 15077:cd6daebf47ae v8.1.0549

patch 8.1.0549: netbeans test depends on README.txt contents commit https://github.com/vim/vim/commit/10efcd5b0259659cd9a152a7a342deb5d56a8eb5 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Nov 26 21:22:07 2018 +0100 patch 8.1.0549: netbeans test depends on README.txt contents Problem: Netbeans test depends on README.txt contents. Solution: Use a generated file instead.
author Bram Moolenaar <Bram@vim.org>
date Mon, 26 Nov 2018 21:30:08 +0100
parents 19ef2bbf569c
children f37561549ec2
line wrap: on
line source

" Vim support file to switch on loading indent files for file types
"
" Maintainer:	Bram Moolenaar <Bram@vim.org>
" Last Change:	2008 Feb 22

if exists("did_indent_on")
  finish
endif
let did_indent_on = 1

augroup filetypeindent
  au FileType * call s:LoadIndent()
  func! s:LoadIndent()
    if exists("b:undo_indent")
      exe b:undo_indent
      unlet! b:undo_indent b:did_indent
    endif
    let s = expand("<amatch>")
    if s != ""
      if exists("b:did_indent")
	unlet b:did_indent
      endif

      " When there is a dot it is used to separate filetype names.  Thus for
      " "aaa.bbb" load "indent/aaa.vim" and then "indent/bbb.vim".
      for name in split(s, '\.')
	exe 'runtime! indent/' . name . '.vim'
      endfor
    endif
  endfunc
augroup END