Mercurial > vim

view src/testdir/test_unlet.vim @ 14806:7cc2d28778ac v8.1.0415

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.0415: not actually using 16 colors with vtp commit https://github.com/vim/vim/commit/d4f73438bb6c88a0d3e315f0eebef30993b5921c Author: Bram Moolenaar <Bram@vim.org> Date: Fri Sep 21 12:24:12 2018 +0200 patch 8.1.0415: not actually using 16 colors with vtp Problem: Not actually using 16 colors with vtp. Solution: Always use 256 colors when vtp is used. (Nobuhiro Takasaki, closes #3432)
author Christian Brabandt <cb@256bit.org>
date Fri, 21 Sep 2018 12:30:06 +0200
parents a94bc6a7b29e
children da98d2ed8dc5
line wrap: on
line source

" Tests for :unlet

func Test_read_only()
  " these caused a crash
  call assert_fails('unlet count', 'E795:')
  call assert_fails('unlet errmsg', 'E795:')
endfunc

func Test_existing()
  let does_exist = 1
  call assert_true(exists('does_exist'))
  unlet does_exist
  call assert_false(exists('does_exist'))
endfunc

func Test_not_existing()
  unlet! does_not_exist
  call assert_fails('unlet does_not_exist', 'E108:')
endfunc

func Test_unlet_fails()
  call assert_fails('unlet v:["count"]', 'E46:')
endfunc

func Test_unlet_env()
  let envcmd = has('win32') ? 'set' : 'env'

  let $FOOBAR = 'test'
  let found = 0
  for kv in split(system(envcmd), "\r*\n")
    if kv == 'FOOBAR=test'
      let found = 1
    endif
  endfor
  call assert_equal(1, found)

  unlet $FOOBAR
  let found = 0
  for kv in split(system(envcmd), "\r*\n")
    if kv == 'FOOBAR=test'
      let found = 1
    endif
  endfor
  call assert_equal(0, found)

  unlet $MUST_NOT_BE_AN_ERROR
endfunc

func Test_unlet_complete()
  let g:FOOBAR = 1
  call feedkeys(":unlet g:FOO\t\n", 'tx')
  call assert_true(!exists('g:FOOBAR'))

  let $FOOBAR = 1
  call feedkeys(":unlet $FOO\t\n", 'tx')
  call assert_true(!exists('$FOOBAR') || empty($FOOBAR))
endfunc