Mercurial > vim

view src/testdir/test_help.vim @ 13503:5d345460c984 v8.0.1625

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1625: test_quotestar is flaky when run in GTK GUI commit https://github.com/vim/vim/commit/29dfa5af3c14406573d08609d2e95add4d6b45fb Author: Bram Moolenaar <Bram@vim.org> Date: Tue Mar 20 21:24:45 2018 +0100 patch 8.0.1625: test_quotestar is flaky when run in GTK GUI Problem: Test_quotestar is flaky when run in GTK GUI. Solution: Do not call lose_selection when invoked from selection_clear_event().
author Christian Brabandt <cb@256bit.org>
date Tue, 20 Mar 2018 21:30:07 +0100
parents e1deb00ffc27
children d0dfb3b0fe31
line wrap: on
line source

" Tests for :help

func Test_help_restore_snapshot()
  help
  set buftype=
  help
  edit x
  help
  helpclose
endfunc

func Test_help_errors()
  call assert_fails('help doesnotexist', 'E149:')
  call assert_fails('help!', 'E478:')

  new
  set keywordprg=:help
  call setline(1, "   ")
  call assert_fails('normal VK', 'E349:')
  bwipe!
endfunc

func Test_help_keyword()
  new
  set keywordprg=:help
  call setline(1, "  Visual ")
  normal VK
  call assert_match('^Visual mode', getline('.'))
  call assert_equal('help', &ft)
  close
  bwipe!
endfunc

func Test_help_local_additions()
  call mkdir('Xruntime/doc', 'p')
  call writefile(['*mydoc.txt* my awesome doc'], 'Xruntime/doc/mydoc.txt')
  call writefile(['*mydoc-ext.txt* my extended awesome doc'], 'Xruntime/doc/mydoc-ext.txt')
  let rtp_save = &rtp
  set rtp+=./Xruntime
  help
  1
  call search('mydoc.txt')
  call assert_equal('|mydoc.txt| my awesome doc', getline('.'))
  1
  call search('mydoc-ext.txt')
  call assert_equal('|mydoc-ext.txt| my extended awesome doc', getline('.'))
  close

  call delete('Xruntime', 'rf')
  let &rtp = rtp_save
endfunc