Mercurial > vim

view src/testdir/test_tabline.vim @ 13088:3dd37eec73f0 v8.0.1419

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1419: cursor column is not updated after ]s commit https://github.com/vim/vim/commit/b73fa629d6d3d705c1f8e8d5f8109fc9abd7bb6f Author: Bram Moolenaar <Bram@vim.org> Date: Thu Dec 21 20:27:47 2017 +0100 patch 8.0.1419: cursor column is not updated after ]s Problem: Cursor column is not updated after ]s. (Gary Johnson) Solution: Set the curswant flag.
author Christian Brabandt <cb@256bit.org>
date Thu, 21 Dec 2017 20:30:06 +0100
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction