Mercurial > vim

view runtime/syntax/wsh.vim @ 12401:eb8d5c4936f1 v8.0.1080

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1080: memory leak for eof_chars terminal option and buffer name commit https://github.com/vim/vim/commit/74121231be50e245d18c64281fdef08e7ec1ed5b Author: Bram Moolenaar <Bram@vim.org> Date: Sat Sep 9 16:34:32 2017 +0200 patch 8.0.1080: memory leak for eof_chars terminal option and buffer name Problem: Memory leak for eof_chars terminal option and buffer name. Solution: Free job options. Free the buffer name
author Christian Brabandt <cb@256bit.org>
date Sat, 09 Sep 2017 16:45:04 +0200
parents a81bc802c17c
children
line wrap: on
line source

" Vim syntax file
" Language:	Windows Scripting Host
" Maintainer:	Paul Moore <pf_moore AT yahoo.co.uk>
" Last Change:	Fre, 24 Nov 2000 21:54:09 +0100

" This reuses the XML, VB and JavaScript syntax files. While VB is not
" VBScript, it's close enough for us. No attempt is made to handle
" other languages.
" Send comments, suggestions and requests to the maintainer.

" Quit when a syntax file was already loaded
if exists("b:current_syntax")
  finish
endif

let s:wsh_cpo_save = &cpo
set cpo&vim

runtime! syntax/xml.vim
unlet b:current_syntax

syn case ignore
syn include @wshVBScript <sfile>:p:h/vb.vim
unlet b:current_syntax
syn include @wshJavaScript <sfile>:p:h/javascript.vim
unlet b:current_syntax
syn region wshVBScript
    \ matchgroup=xmlTag    start="<script[^>]*VBScript\(>\|[^>]*[^/>]>\)"
    \ matchgroup=xmlEndTag end="</script>"
    \ fold
    \ contains=@wshVBScript
    \ keepend
syn region wshJavaScript
    \ matchgroup=xmlTag    start="<script[^>]*J\(ava\)\=Script\(>\|[^>]*[^/>]>\)"
    \ matchgroup=xmlEndTag end="</script>"
    \ fold
    \ contains=@wshJavaScript
    \ keepend

syn cluster xmlRegionHook add=wshVBScript,wshJavaScript

let b:current_syntax = "wsh"

let &cpo = s:wsh_cpo_save
unlet s:wsh_cpo_save