Mercurial > vim

view runtime/syntax/mailcap.vim @ 11727:cb1dc90d22cc v8.0.0746

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0746: when :term fails the job is not properly cleaned up commit https://github.com/vim/vim/commit/61a6605ea1201eb49a126ca696fcfc56caf5dca6 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Jul 22 18:39:00 2017 +0200 patch 8.0.0746: when :term fails the job is not properly cleaned up Problem: When :term fails the job is not properly cleaned up. Solution: Free the terminal. Handle a job that failed to start. (closes #1858)
author Christian Brabandt <cb@256bit.org>
date Sat, 22 Jul 2017 18:45:04 +0200
parents 42bf9264e64e
children
line wrap: on
line source

" Vim syntax file
" Language:	Mailcap configuration file
" Maintainer:	Doug Kearns <dougkearns@gmail.com>
" Last Change:	2013 Jun 01

if exists("b:current_syntax")
  finish
endif

syn match  mailcapComment "^#.*"

syn region mailcapString start=+"+ end=+"+ contains=mailcapSpecial oneline

syn match  mailcapDelimiter "\\\@<!;"

syn match  mailcapSpecial "\\\@<!%[nstF]"
syn match  mailcapSpecial "\\\@<!%{[^}]*}"

syn case ignore
syn match  mailcapFlag	    "\(=\s*\)\@<!\<\(needsterminal\|copiousoutput\|x-\w\+\)\>"
syn match  mailcapFieldname "\<\(compose\|composetyped\|print\|edit\|test\|x11-bitmap\|nametemplate\|textualnewlines\|description\|x-\w+\)\>\ze\s*="
syn match  mailcapTypeField "^\(text\|image\|audio\|video\|application\|message\|multipart\|model\|x-[[:graph:]]\+\)\(/\(\*\|[[:graph:]]\+\)\)\=\ze\s*;"
syn case match

hi def link mailcapComment	Comment
hi def link mailcapDelimiter	Delimiter
hi def link mailcapFlag		Statement
hi def link mailcapFieldname	Statement
hi def link mailcapSpecial	Identifier
hi def link mailcapTypeField	Type
hi def link mailcapString	String

let b:current_syntax = "mailcap"

" vim: ts=8