view runtime/spell/cleanadd.vim @ 11258:84f71a8a5f2c v8.0.0515

patch 8.0.0515: ml_get errors in silent Ex mode commit https://github.com/vim/vim/commit/d5d37537d1fa46fd468bd378af2006dd09840f38 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Mar 27 23:02:07 2017 +0200 patch 8.0.0515: ml_get errors in silent Ex mode Problem: ml_get errors in silent Ex mode. (Dominique Pelle) Solution: Clear valid flags when setting the cursor. Set the topline when not in full screen mode.
author Christian Brabandt <cb@256bit.org>
date Mon, 27 Mar 2017 23:15:05 +0200
parents b9740fb41986
children
line wrap: on
line source

" Vim script to clean the ll.xxxxx.add files of commented out entries
" Author:	Antonio Colombo, Bram Moolenaar
" Last Update:	2008 Jun 3

" Time in seconds after last time an ll.xxxxx.add file was updated
" Default is one second.
" If you invoke this script often set it to something bigger, e.g. 60 * 60
" (one hour)
if !exists("g:spell_clean_limit")
  let g:spell_clean_limit = 1
endif

" Loop over all the runtime/spell/*.add files.
" Delete all comment lines, except the ones starting with ##.
for s:fname in split(globpath(&rtp, "spell/*.add"), "\n")
  if filewritable(s:fname) && localtime() - getftime(s:fname) > g:spell_clean_limit
    if exists('*fnameescape')
      let s:f = fnameescape(s:fname)
    else
      let s:f = escape(s:fname, ' \|<')
    endif
    silent exe "tab split " . s:f
    echo "Processing" s:f
    silent! g/^#[^#]/d
    silent update
    close
    unlet s:f
  endif
endfor
unlet s:fname

echo "Done"