Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 9072:f60bdac6cc2c v7.4.1821

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/4ed6b2e2d7fd5959fb9b9f608935d47305c4bbe4 Author: Bram Moolenaar <Bram@vim.org> Date: Sat May 7 22:28:53 2016 +0200 patch 7.4.1821 Problem: Test fails on MS-Windows. Solution: Sort the completion results.
author Christian Brabandt <cb@256bit.org>
date Sat, 07 May 2016 22:30:05 +0200
parents 0e7b1897ceb3
children 81ba6e4eb72b
line wrap: on
line source

scriptencoding utf-8

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    execute 'call assert_equal("' . $HOME . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('&' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')