runtime(java): Improve the recognition of the "style" method declarations Commit: https://github.com/vim/vim/commit/a4c085a3e607bd01d34e1db600b6460fc35fb0a3 Author: Aliaksei Budavei <0x000c70@gmail.com> Date: Wed Apr 24 21:04:25 2024 +0200 runtime(java): Improve the recognition of the "style" method declarations - Request the new regexp engine (v7.3.970) for [:upper:] and [:lower:]. - Recognise declarations of in-line annotated methods. - Recognise declarations of _strictfp_ methods. - Establish partial order for method modifiers as shown in the MethodModifier production; namely, _public_ and friends should be written the leftmost, possibly followed by _abstract_ or _default_, or possibly followed by other modifiers. - Stop looking for parameterisable primitive types (void<?>, int<Object>, etc., are malformed). - Stop looking for arrays of _void_. - Acknowledge the prevailing convention for method names to begin with a small letter and for class/interface names to begin with a capital letter; and, therefore, desist from claiming declarations of enum constants and constructors with javaFuncDef. Rationale: + Constructor is distinct from method: * its (overloaded) name is not arbitrary; * its return type is implicit; * its _throws_ clause depends on indirect vagaries of instance (variable) initialisers; * its invocation makes other constructors of its type hierarchy invoked one by one, concluding with the primordial constructor; * its explicit invocation, via _this_ or _super_, can only appear as the first statement in a constructor (not anymore, see JEP 447); else, its _super_ call cannot appear in constructors of _record_ or _enum_; and neither invocation is allowed for the primordial constructor; * it is not a member of its class, like initialisers, and is never inherited; * it is never _abstract_ or _native_. + Constructor declarations tend to be few in number and merit visual recognition from method declarations. + Enum constants define a fixed set of type instances and more resemble class variable initialisers. Note that the code duplicated for @javaFuncParams is written keeping in mind for g:java_highlight_functions a pending 3rd variant, which would require none of the :syn-cluster added groups. closes: #14620 Signed-off-by: Aliaksei Budavei <0x000c70@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>

@echo off
rem To be used on MS-Windows for Visual C++ 2017 or later.
rem See INSTALLpc.txt for information.
rem
rem Usage:
rem   For x86 builds run this with "x86" option:
rem     msvc-latest x86
rem   For x64 builds run this with "x86_amd64" option or "x64" option:
rem     msvc-latest x86_amd64
rem     msvc-latest x64
rem
rem Optional environment variables:
rem   VSWHERE:
rem     Full path to vswhere.exe.
rem   VSVEROPT:
rem     Option to search specific version of Visual Studio.
rem     Default: -latest
rem     To search VS2017:
rem       set "VSVEROPT=-version [15.0^,16.0^)"
rem     To search VS2019:
rem       set "VSVEROPT=-version [16.0^,17.0^)"
rem     To search VS2022:
rem       set "VSVEROPT=-version [17.0^,18.0^)"

if "%VSWHERE%"=="" (
	set "VSWHERE=%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"
	set VSWHERE_SET=yes
)
if not exist "%VSWHERE%" (
	echo Error: vswhere not found.
	set VSWHERE=
	set VSWHERE_SET=
	exit /b 1
)

if "%VSVEROPT%"=="" (
	set VSVEROPT=-latest
	set VSVEROPT_SET=yes
)

rem Search Visual Studio Community, Professional or above.
for /f "usebackq tokens=*" %%i in (`"%VSWHERE%" %VSVEROPT% -products * -requires Microsoft.VisualStudio.Component.VC.Tools.x86.x64 -property installationPath`) do (
	set InstallDir=%%i
)
if exist "%InstallDir%\VC\Auxiliary\Build\vcvarsall.bat" (
	call "%InstallDir%\VC\Auxiliary\Build\vcvarsall.bat" %*
	goto done
)

rem Search Visual Studio 2017 Express.
rem (Visual Studio 2017 Express uses different component IDs.)
for /f "usebackq tokens=*" %%i in (`"%VSWHERE%" %VSVEROPT% -products Microsoft.VisualStudio.Product.WDExpress -property installationPath`) do (
	set InstallDir=%%i
)
if exist "%InstallDir%\VC\Auxiliary\Build\vcvarsall.bat" (
	call "%InstallDir%\VC\Auxiliary\Build\vcvarsall.bat" %*
) else (
	echo Error: vcvarsall.bat not found.
	rem Set ERRORLEVEL to 1.
	call
)

:done
if "%VSWHERE_SET%"=="yes" (
	set VSWHERE=
	set VSWHERE_SET=
)
if "%VSVEROPT_SET%"=="yes" (
	set VSVEROPT=
	set VSVEROPT_SET=
)
set InstallDir=