runtime(java): Improve the recognition of the "style" method declarations Commit: https://github.com/vim/vim/commit/a4c085a3e607bd01d34e1db600b6460fc35fb0a3 Author: Aliaksei Budavei <0x000c70@gmail.com> Date: Wed Apr 24 21:04:25 2024 +0200 runtime(java): Improve the recognition of the "style" method declarations - Request the new regexp engine (v7.3.970) for [:upper:] and [:lower:]. - Recognise declarations of in-line annotated methods. - Recognise declarations of _strictfp_ methods. - Establish partial order for method modifiers as shown in the MethodModifier production; namely, _public_ and friends should be written the leftmost, possibly followed by _abstract_ or _default_, or possibly followed by other modifiers. - Stop looking for parameterisable primitive types (void<?>, int<Object>, etc., are malformed). - Stop looking for arrays of _void_. - Acknowledge the prevailing convention for method names to begin with a small letter and for class/interface names to begin with a capital letter; and, therefore, desist from claiming declarations of enum constants and constructors with javaFuncDef. Rationale: + Constructor is distinct from method: * its (overloaded) name is not arbitrary; * its return type is implicit; * its _throws_ clause depends on indirect vagaries of instance (variable) initialisers; * its invocation makes other constructors of its type hierarchy invoked one by one, concluding with the primordial constructor; * its explicit invocation, via _this_ or _super_, can only appear as the first statement in a constructor (not anymore, see JEP 447); else, its _super_ call cannot appear in constructors of _record_ or _enum_; and neither invocation is allowed for the primordial constructor; * it is not a member of its class, like initialisers, and is never inherited; * it is never _abstract_ or _native_. + Constructor declarations tend to be few in number and merit visual recognition from method declarations. + Enum constants define a fixed set of type instances and more resemble class variable initialisers. Note that the code duplicated for @javaFuncParams is written keeping in mind for g:java_highlight_functions a pending 3rd variant, which would require none of the :syn-cluster added groups. closes: #14620 Signed-off-by: Aliaksei Budavei <0x000c70@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>

" Vim syntax file
" Language:     JSON5
" Maintainer:   Mazunki Hoksaas rolferen@gmail.com
" Previous Maintainer: Guten Ye <ywzhaifei@gmail.com>
" Last Change:  2019 Apr 1
" Version:      vim9.0-1
" URL:          https://github.com/json5/json5

" Syntax setup
if exists('b:current_syntax') && b:current_syntax == 'json5'
  finish
endif

" Numbers
syn match   json5Number    "[-+]\=\%(0\|[1-9]\d*\)\%(\.\d*\)\=\%([eE][-+]\=\d\+\)\="
syn match   json5Number    "[-+]\=\%(\.\d\+\)\%([eE][-+]\=\d\+\)\="
syn match   json5Number    "[-+]\=0[xX]\x*"
syn match   json5Number    "[-+]\=Infinity\|NaN"

" An integer part of 0 followed by other digits is not allowed
syn match   json5NumError  "[-+]\=0\d\(\d\|\.\)*"

" A hexadecimal number cannot have a fractional part
syn match   json5NumError  "[-+]\=0x\x*\.\x*"

" Strings
syn region  json5String    start=+"+  skip=+\\\\\|\\"+  end=+"+  contains=json5Escape,@Spell
syn region  json5String    start=+'+  skip=+\\\\\|\\'+  end=+'+  contains=json5Escape,@Spell

" Escape sequences
syn match   json5Escape    "\\['\"\\bfnrtv]" contained
syn match   json5Escape    "\\u\x\{4}" contained

" Boolean
syn keyword json5Boolean   true false

" Null
syn keyword json5Null      null

" Delimiters and Operators
syn match   json5Delimiter  ","
syn match   json5Operator   ":"

" Braces
syn match   json5Braces	   "[{}\[\]]"

" Keys
syn match   json5Key /@\?\%(\I\|\$\)\%(\i\|\$\)*\s*\ze::\@!/ contains=@Spell
syn match   json5Key /"\([^"]\|\\"\)\{-}"\ze\s*:/ contains=json5Escape,@Spell

" Comment
syn region  json5LineComment    start=+\/\/+ end=+$+ keepend contains=@Spell,json5Todo
syn region  json5LineComment    start=+^\s*\/\/+ skip=+\n\s*\/\/+ end=+$+ keepend fold contains=@Spell,json5Todo
syn region  json5Comment        start="/\*"  end="\*/" fold contains=@Spell,json5Todo

syn keyword json5Todo           contained TODO FIXME XXX

" Define the default highlighting
hi def link json5String             String
hi def link json5Key                Identifier
hi def link json5Escape             Special
hi def link json5Number             Number
hi def link json5Delimiter          Delimiter
hi def link json5Operator           Operator
hi def link json5Braces             Delimiter
hi def link json5Null               Keyword
hi def link json5Boolean            Boolean
hi def link json5LineComment        Comment
hi def link json5Comment            Comment
hi def link json5NumError           Error
hi def link json5Todo               Todo

if !exists('b:current_syntax')
  let b:current_syntax = 'json5'
endif