Mercurial > vim

view src/testdir/test_fixeol.vim @ 17478:f9a443306174 v8.1.1737

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1737: :args command that outputs one line gives more prompt commit https://github.com/vim/vim/commit/949f1989cba8bf7653316c2b1444c26f1536bfab Author: Bram Moolenaar <Bram@vim.org> Date: Tue Jul 23 23:00:08 2019 +0200 patch 8.1.1737: :args command that outputs one line gives more prompt Problem: :args command that outputs one line gives more prompt. Solution: Only output line break if needed. (Daniel Hahler, closes https://github.com/vim/vim/issues/4715)
author Bram Moolenaar <Bram@vim.org>
date Tue, 23 Jul 2019 23:15:05 +0200
parents 90aaa974594e
children 08940efa6b4e
line wrap: on
line source

" Tests for 'fixeol' and 'eol'
func Test_fixeol()
  " first write two test files – with and without trailing EOL
  " use Unix fileformat for consistency
  set ff=unix
  enew!
  call setline('.', 'with eol')
  w! XXEol
  enew!
  set noeol nofixeol
  call setline('.', 'without eol')
  w! XXNoEol
  set eol fixeol
  bwipe XXEol XXNoEol

  " try editing files with 'fixeol' disabled
  e! XXEol
  normal ostays eol
  set nofixeol
  w! XXTestEol
  e! XXNoEol
  normal ostays without
  set nofixeol
  w! XXTestNoEol
  bwipe! XXEol XXNoEol XXTestEol XXTestNoEol
  set fixeol

  " Append "END" to each file so that we can see what the last written char
  " was.
  normal ggdGaEND
  w >>XXEol
  w >>XXNoEol
  w >>XXTestEol
  w >>XXTestNoEol

  call assert_equal(['with eol', 'END'], readfile('XXEol'))
  call assert_equal(['without eolEND'], readfile('XXNoEol'))
  call assert_equal(['with eol', 'stays eol', 'END'], readfile('XXTestEol'))
  call assert_equal(['without eol', 'stays withoutEND'],
	      \ readfile('XXTestNoEol'))

  call delete('XXEol')
  call delete('XXNoEol')
  call delete('XXTestEol')
  call delete('XXTestNoEol')
  set ff& fixeol& eol&
  enew!
endfunc