Mercurial > vim

view src/testdir/test_tabline.vim @ 18207:f93c2b6f7167 v8.1.2098

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.2098: mksession test fails on MS-Windows Commit: https://github.com/vim/vim/commit/37ac4a531ce58daa201e3e045ef553734eaa432a Author: Bram Moolenaar <Bram@vim.org> Date: Sat Sep 28 19:29:04 2019 +0200 patch 8.1.2098: mksession test fails on MS-Windows Problem: mksession test fails on MS-Windows. Solution: Skip testing with backslashes on MS-Windows.
author Bram Moolenaar <Bram@vim.org>
date Sat, 28 Sep 2019 19:30:03 +0200
parents 325e4a8ba1b6
children 0650d220f742
line wrap: on
line source


source shared.vim

func TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunc

func TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunc

func Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunc

func Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunc

func Test_redrawtabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  set tabline=%{bufnr('$')}
  edit Xtabline1
  edit Xtabline2
  redraw
  call assert_match(bufnr('$') . '', Screenline(1))
  au BufAdd * redrawtabline
  badd Xtabline3
  call assert_match(bufnr('$') . '', Screenline(1))

  set tabline=
  let &showtabline = showtabline_save
  au! Bufadd
endfunc