Mercurial > vim

view runtime/syntax/services.vim @ 16788:f7268ec2c889 v8.1.1396

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1396: 'wincolor' does not apply to lines below the buffer commit https://github.com/vim/vim/commit/193ffd1d9f4f4d5412ce8d7a46bb2f89d47a56da Author: Bram Moolenaar <Bram@vim.org> Date: Sat May 25 22:57:30 2019 +0200 patch 8.1.1396: 'wincolor' does not apply to lines below the buffer Problem: 'wincolor' does not apply to lines below the buffer. Solution: Also apply 'wincolor' to the "~" lines and the number column.
author Bram Moolenaar <Bram@vim.org>
date Sat, 25 May 2019 23:00:04 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             services(5) - Internet network services list
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   servicesBegin     display '^'
                              \ nextgroup=servicesName,servicesComment

syn match   servicesName      contained display '[[:graph:]]\+'
                              \ nextgroup=servicesPort skipwhite

syn match   servicesPort      contained display '\d\+'
                              \ nextgroup=servicesPPDiv,servicesPPDivDepr
                              \ skipwhite

syn match   servicesPPDiv     contained display '/'
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesPPDivDepr contained display ','
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesProtocol  contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn match   servicesAliases   contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn keyword servicesTodo      contained TODO FIXME XXX NOTE

syn region  servicesComment   display oneline start='#' end='$'
                              \ contains=servicesTodo,@Spell

hi def link servicesTodo      Todo
hi def link servicesComment   Comment
hi def link servicesName      Identifier
hi def link servicesPort      Number
hi def link servicesPPDiv     Delimiter
hi def link servicesPPDivDepr Error
hi def link servicesProtocol  Type
hi def link servicesAliases   Macro

let b:current_syntax = "services"

let &cpo = s:cpo_save
unlet s:cpo_save