view runtime/indent/gitconfig.vim @ 16734:e3feaa3e5f10 v8.1.1369

patch 8.1.1369: get E484 when using system() during GUI startup commit https://github.com/vim/vim/commit/294d9bf966bbbcb0b49affb9b15534d5b9c93801 Author: Bram Moolenaar <Bram@vim.org> Date: Thu May 23 20:12:46 2019 +0200 patch 8.1.1369: get E484 when using system() during GUI startup Problem: Get E484 when using system() during GUI startup. Solution: Check "gui.starting". (Ken Takata)
author Bram Moolenaar <Bram@vim.org>
date Thu, 23 May 2019 20:15:05 +0200
parents 63b0b7b79b25
children
line wrap: on
line source

" Vim indent file
" Language:	git config file
" Maintainer:	Tim Pope <vimNOSPAM@tpope.org>
" Last Change:	2017 Jun 13

if exists("b:did_indent")
  finish
endif
let b:did_indent = 1

setlocal autoindent
setlocal indentexpr=GetGitconfigIndent()
setlocal indentkeys=o,O,*<Return>,0[,],0;,0#,=,!^F

let b:undo_indent = 'setl ai< inde< indk<'

" Only define the function once.
if exists("*GetGitconfigIndent")
  finish
endif

function! GetGitconfigIndent()
  let sw    = shiftwidth()
  let line  = getline(prevnonblank(v:lnum-1))
  let cline = getline(v:lnum)
  if line =~  '\\\@<!\%(\\\\\)*\\$'
    " odd number of slashes, in a line continuation
    return 2 * sw
  elseif cline =~ '^\s*\['
    return 0
  elseif cline =~ '^\s*\a'
    return sw
  elseif cline == ''       && line =~ '^\['
    return sw
  else
    return -1
  endif
endfunction