Mercurial > vim

view src/testdir/test_unlet.vim @ 16869:e264d45f268a v8.1.1436

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1436: writefile test fails when run under /tmp commit https://github.com/vim/vim/commit/c28cb5b16df76353a5995fda3b9341612b8630c1 Author: Bram Moolenaar <Bram@vim.org> Date: Fri May 31 20:42:09 2019 +0200 patch 8.1.1436: writefile test fails when run under /tmp Problem: Writefile test fails when run under /tmp. Solution: Adjust 'backupskip. (Kenta Sato, closes https://github.com/vim/vim/issues/4462)
author Bram Moolenaar <Bram@vim.org>
date Fri, 31 May 2019 20:45:04 +0200
parents a94bc6a7b29e
children da98d2ed8dc5
line wrap: on
line source

" Tests for :unlet

func Test_read_only()
  " these caused a crash
  call assert_fails('unlet count', 'E795:')
  call assert_fails('unlet errmsg', 'E795:')
endfunc

func Test_existing()
  let does_exist = 1
  call assert_true(exists('does_exist'))
  unlet does_exist
  call assert_false(exists('does_exist'))
endfunc

func Test_not_existing()
  unlet! does_not_exist
  call assert_fails('unlet does_not_exist', 'E108:')
endfunc

func Test_unlet_fails()
  call assert_fails('unlet v:["count"]', 'E46:')
endfunc

func Test_unlet_env()
  let envcmd = has('win32') ? 'set' : 'env'

  let $FOOBAR = 'test'
  let found = 0
  for kv in split(system(envcmd), "\r*\n")
    if kv == 'FOOBAR=test'
      let found = 1
    endif
  endfor
  call assert_equal(1, found)

  unlet $FOOBAR
  let found = 0
  for kv in split(system(envcmd), "\r*\n")
    if kv == 'FOOBAR=test'
      let found = 1
    endif
  endfor
  call assert_equal(0, found)

  unlet $MUST_NOT_BE_AN_ERROR
endfunc

func Test_unlet_complete()
  let g:FOOBAR = 1
  call feedkeys(":unlet g:FOO\t\n", 'tx')
  call assert_true(!exists('g:FOOBAR'))

  let $FOOBAR = 1
  call feedkeys(":unlet $FOO\t\n", 'tx')
  call assert_true(!exists('$FOOBAR') || empty($FOOBAR))
endfunc