Mercurial > vim

view runtime/syntax/services.vim @ 20749:dae1811e84dd v8.2.0927

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0927: some sshconfig and ssdhconfig files are not recognized Commit: https://github.com/vim/vim/commit/da84ac2a6f467d0b9eddcc8709433cda75d16a41 Author: Bram Moolenaar <Bram@vim.org> Date: Sun Jun 7 20:07:43 2020 +0200 patch 8.2.0927: some sshconfig and ssdhconfig files are not recognized Problem: Some sshconfig and ssdhconfig files are not recognized. Solution: Add filetype patterns.
author Bram Moolenaar <Bram@vim.org>
date Sun, 07 Jun 2020 20:15:03 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             services(5) - Internet network services list
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   servicesBegin     display '^'
                              \ nextgroup=servicesName,servicesComment

syn match   servicesName      contained display '[[:graph:]]\+'
                              \ nextgroup=servicesPort skipwhite

syn match   servicesPort      contained display '\d\+'
                              \ nextgroup=servicesPPDiv,servicesPPDivDepr
                              \ skipwhite

syn match   servicesPPDiv     contained display '/'
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesPPDivDepr contained display ','
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesProtocol  contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn match   servicesAliases   contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn keyword servicesTodo      contained TODO FIXME XXX NOTE

syn region  servicesComment   display oneline start='#' end='$'
                              \ contains=servicesTodo,@Spell

hi def link servicesTodo      Todo
hi def link servicesComment   Comment
hi def link servicesName      Identifier
hi def link servicesPort      Number
hi def link servicesPPDiv     Delimiter
hi def link servicesPPDivDepr Error
hi def link servicesProtocol  Type
hi def link servicesAliases   Macro

let b:current_syntax = "services"

let &cpo = s:cpo_save
unlet s:cpo_save