view runtime/syntax/alsaconf.vim @ 10386:d3f0946b4a80 v8.0.0087

commit https://github.com/vim/vim/commit/7df915d113ac1981792c50e8b000c9f5f784b78b Author: Bram Moolenaar <Bram@vim.org> Date: Thu Nov 17 17:25:32 2016 +0100 patch 8.0.0087 Problem: When the channel callback gets job info the job may already have been deleted. (lifepillar) Solution: Do not delete the job when the channel is still useful. (ichizok, closes #1242, closes #1245)
author Christian Brabandt <cb@256bit.org>
date Thu, 17 Nov 2016 17:30:04 +0100
parents 1f3b1021f002
children 1218c5353e2b
line wrap: on
line source

" Vim syntax file
" Language:         alsaconf(8) configuration file
" Maintainer:       Nikolai Weibull <now@bitwi.se>
" Latest Revision:  2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn keyword alsoconfTodo        contained FIXME TODO XXX NOTE

syn region  alsaconfComment     display oneline
                                \ start='#' end='$'
                                \ contains=alsaconfTodo,@Spell

syn match   alsaconfSpecialChar contained display '\\[ntvbrf]'
syn match   alsaconfSpecialChar contained display '\\\o\+'

syn region  alsaconfString      start=+"+ skip=+\\$+ end=+"\|$+
                                \ contains=alsaconfSpecialChar

syn match   alsaconfSpecial     contained display 'confdir:'

syn region  alsaconfPreProc     start='<' end='>' contains=alsaconfSpecial

syn match   alsaconfMode        display '[+?!-]'

syn keyword alsaconfKeyword     card default device errors files func strings
syn keyword alsaconfKeyword     subdevice type vars

syn match   alsaconfVariables   display '@\(hooks\|func\|args\)'

hi def link alsoconfTodo        Todo
hi def link alsaconfComment     Comment
hi def link alsaconfSpecialChar SpecialChar
hi def link alsaconfString      String
hi def link alsaconfSpecial     Special
hi def link alsaconfPreProc     PreProc
hi def link alsaconfMode        Special
hi def link alsaconfKeyword     Keyword
hi def link alsaconfVariables   Identifier

let b:current_syntax = "alsaconf"

let &cpo = s:cpo_save
unlet s:cpo_save