Mercurial > vim

view runtime/syntax/scdoc.vim @ 27726:d3ed8b1a7bde v8.2.4389

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.4389: screenpos() does not handle a position in a closed fold Commit: https://github.com/vim/vim/commit/4556a2e8681c5c98fb4c7ca0a016924a69b4452a Author: Bram Moolenaar <Bram@vim.org> Date: Tue Feb 15 13:40:17 2022 +0000 patch 8.2.4389: screenpos() does not handle a position in a closed fold Problem: screenpos() does not handle a position in a closed fold. Solution: Check if the position is inside a closed fold. (closes https://github.com/vim/vim/issues/9778)
author Bram Moolenaar <Bram@vim.org>
date Tue, 15 Feb 2022 14:45:03 +0100
parents 29ec2c198c8d
children cd68a630f0d0
line wrap: on
line source

" Syntax file for scdoc files
" Maintainer: Gregory Anders <greg@gpanders.com>
" Last Updated: 2021-08-04

if exists('b:current_syntax')
    finish
endif
let b:current_syntax = 'scdoc'

syntax match scdocFirstLineError "\%^.*$"
syntax match scdocFirstLineValid "\%^\S\+(\d[0-9A-Za-z]*)\%(\s\+\"[^"]*\"\%(\s\+\"[^"]*\"\)\=\)\=$"

syntax region scdocCommentError start="^;\S" end="$" keepend
syntax region scdocComment start="^; " end="$" keepend

syntax region scdocHeaderError start="^#\{3,}" end="$" keepend
syntax region scdocHeader start="^#\{1,2}" end="$" keepend

syntax match scdocIndentError "^[ ]\+"

syntax match scdocLineBreak "++$"

syntax match scdocOrderedListMarker "^\s*\.\%(\s\+\S\)\@="
syntax match scdocListMarker "^\s*-\%(\s\+\S\)\@="

syntax match scdocTableStartMarker "^[\[|\]][\[\-\]]"
syntax match scdocTableMarker "^[|:][\[\-\] ]"

syntax region scdocBold concealends matchgroup=scdocBoldDelimiter start="\\\@<!\*" end="\\\@<!\*"
syntax region scdocUnderline concealends matchgroup=scdocUnderlineDelimiter start="\<\\\@<!_" end="\\\@<!_\>"
syntax region scdocPre matchgroup=scdocPreDelimiter start="^\t*```" end="^\t*```"

hi link scdocFirstLineValid     Comment
hi link scdocComment            Comment
hi link scdocHeader             Title
hi link scdocOrderedListMarker  Statement
hi link scdocListMarker         scdocOrderedListMarker
hi link scdocLineBreak          Special
hi link scdocTableMarker        Statement
hi link scdocTableStartMarker   scdocTableMarker

hi link scdocFirstLineError     Error
hi link scdocCommentError       Error
hi link scdocHeaderError        Error
hi link scdocIndentError        Error

hi link scdocPreDelimiter       Delimiter

hi scdocBold term=bold cterm=bold gui=bold
hi scdocUnderline term=underline cterm=underline gui=underline
hi link scdocBoldDelimiter scdocBold
hi link scdocUnderlineDelimiter scdocUnderline