view runtime/syntax/pacmanlog.vim @ 34651:d299b4b3099f v9.1.0210

patch 9.1.0210: Motif: leaking memory when mui_mch_dialog() fails Commit: https://github.com/vim/vim/commit/9ccc2972373c8310c20ae7621b9c634d0dc43e26 Author: Christian Brabandt <cb@256bit.org> Date: Tue Mar 26 18:44:48 2024 +0100 patch 9.1.0210: Motif: leaking memory when mui_mch_dialog() fails Problem: Motif: leaking memory when mui_mch_dialog() fails (LuMingYinDetect) Solution: When allocating the label using the XmStringCreateLtoR() function fails, before returning also free the allocated buttons pointer. fixes: #14247 closes: #14280 Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Tue, 26 Mar 2024 19:00:03 +0100
parents eb3f61da6d5e
children
line wrap: on
line source

" Vim syntax file
" Language: pacman.log
" Maintainer: Ronan Pigott <ronan@rjp.ie>
" Last Change: 2023 Dec 04

if exists("b:current_syntax")
  finish
endif

syn sync maxlines=1
syn region pacmanlogMsg start='\S' end='$' keepend contains=pacmanlogTransaction,pacmanlogALPMMsg
syn region pacmanlogTag start='\['hs=s+1 end='\]'he=e-1 keepend nextgroup=pacmanlogMsg
syn region pacmanlogTime start='^\['hs=s+1 end='\]'he=e-1 keepend nextgroup=pacmanlogTag

syn match pacmanlogPackageName '\v[a-z0-9@_+.-]+' contained skipwhite nextgroup=pacmanlogPackageVersion
syn match pacmanlogPackageVersion '(.*)' contained

syn match pacmanlogTransaction 'transaction \v(started|completed)$' contained
syn match pacmanlogInstalled   '\v(re)?installed' contained nextgroup=pacmanlogPackageName
syn match pacmanlogUpgraded    'upgraded'         contained nextgroup=pacmanlogPackageName
syn match pacmanlogDowngraded  'downgraded'       contained nextgroup=pacmanlogPackageName
syn match pacmanlogRemoved     'removed'          contained nextgroup=pacmanlogPackageName
syn match pacmanlogWarning     'warning:.*$'      contained

syn region pacmanlogALPMMsg start='\v(\[ALPM\] )@<=(transaction|(re)?installed|upgraded|downgraded|removed|warning)>' end='$' contained
	\ contains=pacmanlogTransaction,pacmanlogInstalled,pacmanlogUpgraded,pacmanlogDowngraded,pacmanlogRemoved,pacmanlogWarning,pacmanlogPackageName,pacmanlogPackgeVersion

hi def link pacmanlogTime String
hi def link pacmanlogTag  Type

hi def link pacmanlogTransaction Special
hi def link pacmanlogInstalled   Identifier
hi def link pacmanlogRemoved     Repeat
hi def link pacmanlogUpgraded    pacmanlogInstalled
hi def link pacmanlogDowngraded  pacmanlogRemoved
hi def link pacmanlogWarning     WarningMsg

hi def link pacmanlogPackageName    Normal
hi def link pacmanlogPackageVersion Comment

let b:current_syntax = "pacmanlog"