view runtime/ftplugin/gprof.vim @ 28289:cdaff4db7760 v8.2.4670

patch 8.2.4670: memory allocation failures for new tab page not tested Commit: https://github.com/vim/vim/commit/72bb47e38f6805050ed6d969f17591bed71f83d4 Author: Yegappan Lakshmanan <yegappan@yahoo.com> Date: Sun Apr 3 11:22:38 2022 +0100 patch 8.2.4670: memory allocation failures for new tab page not tested Problem: Memory allocation failures for new tab page not tested. Solution: Add tests with failing memory allocation. (Yegappan Lakshmanan, closes #10067)
author Bram Moolenaar <Bram@vim.org>
date Sun, 03 Apr 2022 12:30:03 +0200
parents 65de67669df3
children
line wrap: on
line source

" Language:     gprof
" Maintainer:   Dominique Pelle <dominique.pelle@gmail.com>
" Contributors: Doug Kearns <dougkearns@gmail.com>
" Last Change:  2021 Sep 19

" When cursor is on one line of the gprof call graph,
" calling this function jumps to this function in the call graph.
if exists("b:did_ftplugin")
  finish
endif
let b:did_ftplugin=1

func! <SID>GprofJumpToFunctionIndex()
  let l:line = getline('.')
  if l:line =~ '[\d\+\]$'
    " We're in a line in the call graph.
    norm! $y%
    call search('^' . escape(@", '[]'), 'sw')
    norm! zz
  elseif l:line =~ '^\(\s*[0-9\.]\+\)\{3}\s\+'
    " We're in line in the flat profile.
    norm! 55|eby$
    call search('^\[\d\+\].*\d\s\+' .  escape(@", '[]*.') . '\>', 'sW')
    norm! zz
  endif
endfunc

if !exists("no_plugin_maps") && !exists("no_gprof_maps")
  " Pressing <C-]> on a line in the gprof flat profile or in
  " the call graph, jumps to the corresponding function inside
  " the flat profile.
  map <buffer> <silent> <C-]> :call <SID>GprofJumpToFunctionIndex()<CR>
  let b:undo_ftplugin = "silent! unmap <buffer> <C-]>"
endif

" vim:sw=2 fdm=indent