Mercurial > vim

view src/testdir/test_fixeol.vim @ 18376:ccc02b39fb5e v8.1.2182

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.2182: test42 seen as binary by git diff Commit: https://github.com/vim/vim/commit/5b39d7adb0b9f02afe242f607d4c96250f06965d Author: Bram Moolenaar <Bram@vim.org> Date: Sat Oct 19 18:37:53 2019 +0200 patch 8.1.2182: test42 seen as binary by git diff Problem: Test42 seen as binary by git diff. Solution: Add .gitattributes file. Make explicit that 'cpo' does not contain 'S'. (Daniel Hahler, closes #5072)
author Bram Moolenaar <Bram@vim.org>
date Sat, 19 Oct 2019 18:45:03 +0200
parents 90aaa974594e
children 08940efa6b4e
line wrap: on
line source

" Tests for 'fixeol' and 'eol'
func Test_fixeol()
  " first write two test files – with and without trailing EOL
  " use Unix fileformat for consistency
  set ff=unix
  enew!
  call setline('.', 'with eol')
  w! XXEol
  enew!
  set noeol nofixeol
  call setline('.', 'without eol')
  w! XXNoEol
  set eol fixeol
  bwipe XXEol XXNoEol

  " try editing files with 'fixeol' disabled
  e! XXEol
  normal ostays eol
  set nofixeol
  w! XXTestEol
  e! XXNoEol
  normal ostays without
  set nofixeol
  w! XXTestNoEol
  bwipe! XXEol XXNoEol XXTestEol XXTestNoEol
  set fixeol

  " Append "END" to each file so that we can see what the last written char
  " was.
  normal ggdGaEND
  w >>XXEol
  w >>XXNoEol
  w >>XXTestEol
  w >>XXTestNoEol

  call assert_equal(['with eol', 'END'], readfile('XXEol'))
  call assert_equal(['without eolEND'], readfile('XXNoEol'))
  call assert_equal(['with eol', 'stays eol', 'END'], readfile('XXTestEol'))
  call assert_equal(['without eol', 'stays withoutEND'],
	      \ readfile('XXTestNoEol'))

  call delete('XXEol')
  call delete('XXNoEol')
  call delete('XXTestEol')
  call delete('XXTestNoEol')
  set ff& fixeol& eol&
  enew!
endfunc