runtime(dist): centralize safe executable check and add vim library (#13413) Commit: https://github.com/vim/vim/commit/cd8a3eaf5348feacfecab4b374b7ea4ce6a97422 Author: D. Ben Knoble <ben.knoble+github@gmail.com> Date: Sat Nov 4 05:11:17 2023 -0400 runtime(dist): centralize safe executable check and add vim library (https://github.com/vim/vim/issues/13413) Follow up to 816fbcc26 (patch 9.0.1833: [security] runtime file fixes, 2023-08-31) and f7ac0ef50 (runtime: don't execute external commands when loading ftplugins, 2023-09-06). This puts the logic for safe executable checks in a single place, by introducing a central vim library, so all filetypes benefit from consistency. Notable changes: - dist#vim because the (autoload) namespace for a new runtime support library. Supporting functions should get documentation. It might make life easier for NeoVim devs to make the documentation a new file rather than cram it into existing files, though we may want cross-references to it somewhere? - The gzip and zip plugins need to be opted into by enabling execution of those programs (or the global plugin_exec). This needs documentation or discussion. - This fixes a bug in the zig plugin: code setting s:tmp_cwd was removed in f7ac0ef50 (runtime: don't execute external commands when loading ftplugins, 2023-09-06), but the variable was still referenced. Since the new function takes care of that automatically, the variable is no longer needed. Signed-off-by: D. Ben Knoble <ben.knoble+github@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>

" Vim filetype plugin
" Language:		awk, nawk, gawk, mawk
" Maintainer:		Doug Kearns <dougkearns@gmail.com>
" Previous Maintainer:	Antonio Colombo <azc100@gmail.com>
" Last Change:		2020 Sep 28

" This plugin was prepared by Mark Sikora
" This plugin was updated as proposed by Doug Kearns

" Only do this when not done yet for this buffer
if exists("b:did_ftplugin")
  finish
endif

" Don't load another plugin for this buffer
let b:did_ftplugin = 1

let s:cpo_save = &cpo
set cpo&vim

setlocal comments=:#
setlocal commentstring=#\ %s
setlocal formatoptions-=t formatoptions+=croql

setlocal define=function
setlocal suffixesadd+=.awk

let b:undo_ftplugin = "setl fo< com< cms< def< sua<" .
		    \ " | unlet! b:browsefilter"

" TODO: set this in scripts.vim?
if exists("g:awk_is_gawk")
  setlocal include=@include
  setlocal suffixesadd+=.gawk
  if has("unix") || has("win32unix")
    setlocal formatprg=gawk\ -f-\ -o/dev/stdout
    let b:undo_ftplugin .= " | setl fp<"
  endif

  " Disabled by default for security reasons.
  if dist#vim#IsSafeExecutable('awk', 'gawk')
    let path = system("gawk 'BEGIN { printf ENVIRON[\"AWKPATH\"] }'")
    let path = substitute(path, '^\.\=:\|:\.\=$\|:\.\=:', ',,', 'g') " POSIX cwd
    let path = substitute(path, ':', ',', 'g')

    let &l:path = path
  endif
  let b:undo_ftplugin .= " | setl inc< path<"
endif

if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
  let b:browsefilter = "Awk Source Files (*.awk,*.gawk)\t*.awk;*.gawk\n" .
		     \ "All Files (*.*)\t*.*\n"
endif

let &cpo = s:cpo_save
unlet s:cpo_save

" vim: nowrap sw=2 sts=2 ts=8