Mercurial > vim

view src/testdir/test_tabline.vim @ 18819:ba8dc10a2c0d v8.1.2397

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.2397: should not define __USE_XOPEN Commit: https://github.com/vim/vim/commit/e7dd0deb3c4c4b1f55e28e5fe9a4ef4b76951b85 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Dec 5 23:07:06 2019 +0100 patch 8.1.2397: should not define __USE_XOPEN Problem: Should not define __USE_XOPEN. _XOPEN_SOURCE is not needed for Android. Solution: Remove __USE_XOPEN and adjust #ifdefs. (Ozaki Kiichi, closes #5322)
author Bram Moolenaar <Bram@vim.org>
date Thu, 05 Dec 2019 23:15:04 +0100
parents 325e4a8ba1b6
children 0650d220f742
line wrap: on
line source


source shared.vim

func TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunc

func TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunc

func Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunc

func Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunc

func Test_redrawtabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  set tabline=%{bufnr('$')}
  edit Xtabline1
  edit Xtabline2
  redraw
  call assert_match(bufnr('$') . '', Screenline(1))
  au BufAdd * redrawtabline
  badd Xtabline3
  call assert_match(bufnr('$') . '', Screenline(1))

  set tabline=
  let &showtabline = showtabline_save
  au! Bufadd
endfunc