Mercurial > vim

view src/testdir/test_tabline.vim @ 13628:b59806681b98 v8.0.1686

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1686: Python does not work when configuring with specific dir commit https://github.com/vim/vim/commit/d088240b96bc8b2bdba9242dcb9e3d36f1e16c48 Author: Bram Moolenaar <Bram@vim.org> Date: Tue Apr 10 18:13:05 2018 +0200 patch 8.0.1686: Python does not work when configuring with specific dir Problem: Python does not work when configuring with specific dir. (Rajdeep) Solution: Do define PYTHON_HOME and PYTHON3_HOME in configure if the Python config dir was specified.
author Christian Brabandt <cb@256bit.org>
date Tue, 10 Apr 2018 18:15:07 +0200
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction