Mercurial > vim

view src/msvc-latest.bat @ 36242:b2a5d49fcedb

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
runtime(comment): consider &tabstop in lines after whitespace indent Commit: https://github.com/vim/vim/commit/7b27fc49a8c4ce480f759dc33082e6150fb94238 Author: Konfekt <Konfekt@users.noreply.github.com> Date: Sat Oct 5 16:17:04 2024 +0200 runtime(comment): consider &tabstop in lines after whitespace indent The count `strlen()` in ```vim line = printf(indent_start .. substitute(cms, '%s\@!', '%%', 'g'), strpart(getline(lnum), strlen(indent_start))) ``` is too large if the block of lines to be operated on contains different whitespace indenting (tab vs. spaces). Considering using `2gcc` on the first line with 4 spaces as indenting and on the next line using a single tab character (with &tabstop value of 8): Using `strlen(indent_start) = 4` for an initial indent of 4 spaces is correct for the first line, but wrong for the next line and will therefore wrongly comment out the tab-indented line (and possibly deleting some content). The new check is still too simple because it assumes that as soon as there's a tab the whole indent is made of tabs; it's a start of entering the mixed tab and whitespace indent rabbit hole. fixes: #15797 closes: #15805 Signed-off-by: Konfekt <Konfekt@users.noreply.github.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Sat, 05 Oct 2024 16:30:07 +0200
parents 54dda39c5bb3
children
line wrap: on
line source

@echo off
rem To be used on MS-Windows for Visual C++ 2017 or later.
rem See INSTALLpc.txt for information.
rem
rem Usage:
rem   For x86 builds run this with "x86" option:
rem     msvc-latest x86
rem   For x64 builds run this with "x86_amd64" option or "x64" option:
rem     msvc-latest x86_amd64
rem     msvc-latest x64
rem
rem Optional environment variables:
rem   VSWHERE:
rem     Full path to vswhere.exe.
rem   VSVEROPT:
rem     Option to search specific version of Visual Studio.
rem     Default: -latest
rem     To search VS2017:
rem       set "VSVEROPT=-version [15.0^,16.0^)"
rem     To search VS2019:
rem       set "VSVEROPT=-version [16.0^,17.0^)"
rem     To search VS2022:
rem       set "VSVEROPT=-version [17.0^,18.0^)"

if "%VSWHERE%"=="" (
	set "VSWHERE=%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"
	set VSWHERE_SET=yes
)
if not exist "%VSWHERE%" (
	echo Error: vswhere not found.
	set VSWHERE=
	set VSWHERE_SET=
	exit /b 1
)

if "%VSVEROPT%"=="" (
	set VSVEROPT=-latest
	set VSVEROPT_SET=yes
)

rem Search Visual Studio Community, Professional or above.
for /f "usebackq tokens=*" %%i in (`"%VSWHERE%" %VSVEROPT% -products * -requires Microsoft.VisualStudio.Component.VC.Tools.x86.x64 -property installationPath`) do (
	set InstallDir=%%i
)
if exist "%InstallDir%\VC\Auxiliary\Build\vcvarsall.bat" (
	call "%InstallDir%\VC\Auxiliary\Build\vcvarsall.bat" %*
	goto done
)

rem Search Visual Studio 2017 Express.
rem (Visual Studio 2017 Express uses different component IDs.)
for /f "usebackq tokens=*" %%i in (`"%VSWHERE%" %VSVEROPT% -products Microsoft.VisualStudio.Product.WDExpress -property installationPath`) do (
	set InstallDir=%%i
)
if exist "%InstallDir%\VC\Auxiliary\Build\vcvarsall.bat" (
	call "%InstallDir%\VC\Auxiliary\Build\vcvarsall.bat" %*
) else (
	echo Error: vcvarsall.bat not found.
	rem Set ERRORLEVEL to 1.
	call
)

:done
if "%VSWHERE_SET%"=="yes" (
	set VSWHERE=
	set VSWHERE_SET=
)
if "%VSVEROPT_SET%"=="yes" (
	set VSVEROPT=
	set VSVEROPT_SET=
)
set InstallDir=